Recommended Posts

Jag fick ett behov av att skicka ett Excel-blad med e-mail. Men jag hittar inget kommando för att göra något sådant. Varken på Excelsidan eller i Outlook.

Hur gör man?

Jag har Excel i Office och Outlook, Win 10 och Explorer 11.

Dela detta inlägg


Länk till inlägg
Dela på andra webbplatser

menar du som ett tillägg så är det bara att göra som vanligt när du skickar en fil.

I outlook väljer du att "bifoga fil" sedan väljer du ditt excel dokument

Dela detta inlägg


Länk till inlägg
Dela på andra webbplatser

Eller om du är bekväm i att skapa macron..

Kopiera och klistra in koden för att skapa ett macro som du kan skicka e-post i Excel med. Det skickar bara den aktiva arbetsboken och inte hela dokumentet.

Döp modulen till SkickaEpost eller något du vet vad det är. När det är dags att skicka klickar du Alt+F8 för att köra ett makro. Då väljer du det du nyss skapat och klickar ok. Fyll i e-postadress och ämne.. klicka skicka.

Sub Mail_ActiveSheet()
'For Tips see: http://www.rondebruin.nl/win/winmail/div/tips.htm
'Working in Excel 2000-2016
    Dim FileExtStr As String
    Dim FileFormatNum As Long
    Dim Sourcewb As Workbook
    Dim Destwb As Workbook
    Dim TempFilePath As String
    Dim TempFileName As String
    Dim I As Long

    With Application
        .ScreenUpdating = False
        .EnableEvents = False
    End With

    Set Sourcewb = ActiveWorkbook

    'Copy the sheet to a new workbook
    ActiveSheet.Copy
    Set Destwb = ActiveWorkbook

    'Determine the Excel version and file extension/format
    With Destwb
        If Val(Application.Version) < 12 Then
            'You use Excel 97-2003
            FileExtStr = ".xls": FileFormatNum = -4143
        Else
            'You use Excel 2007-2016
            Select Case Sourcewb.FileFormat
            Case 51: FileExtStr = ".xlsx": FileFormatNum = 51
            Case 52:
                If .HasVBProject Then
                    FileExtStr = ".xlsm": FileFormatNum = 52
                Else
                    FileExtStr = ".xlsx": FileFormatNum = 51
                End If
            Case 56: FileExtStr = ".xls": FileFormatNum = 56
            Case Else: FileExtStr = ".xlsb": FileFormatNum = 50
            End Select
        End If

    End With

    '    'Change all cells in the worksheet to values if you want
    '    With Destwb.Sheets(1).UsedRange
    '        .Cells.Copy
    '        .Cells.PasteSpecial xlPasteValues
    '        .Cells(1).Select
    '    End With
    '    Application.CutCopyMode = False

    'Save the new workbook/Mail it/Delete it
    TempFilePath = Environ$("temp") & "\"
    TempFileName = "Part of " & Sourcewb.Name & " " _
                 & Format(Now, "dd-mmm-yy h-mm-ss")

    With Destwb
        .SaveAs TempFilePath & TempFileName & FileExtStr, _
                FileFormat:=FileFormatNum
        On Error Resume Next
        For I = 1 To 3
            .SendMail "", _
                      "This is the Subject line"
            If Err.Number = 0 Then Exit For
        Next I
        On Error GoTo 0
        .Close SaveChanges:=False
    End With

    'Delete the file you have send
    Kill TempFilePath & TempFileName & FileExtStr

    With Application
        .ScreenUpdating = True
        .EnableEvents = True
    End With
End Sub

 

Dela detta inlägg


Länk till inlägg
Dela på andra webbplatser

Tack för dina råd och tips. Det var ungefär så enkelt som du föreslog i första inlägget.

I Excel fanns det (hittade ingen) ingen knapp för att skicka med e-mail. Men jag såg efteråt i Word att det finns en "Senaste öppnade filer" och där fanns Excel-filen. Så det var bara att klicka på Infoga i e-mailen och välja dokument. Då kom jag precis rätt.

Dela detta inlägg


Länk till inlägg
Dela på andra webbplatser
1 timme sedan, -64 sade:

Tack för dina råd och tips. Det var ungefär så enkelt som du föreslog i första inlägget.

I Excel fanns det (hittade ingen) ingen knapp för att skicka med e-mail. Men jag såg efteråt i Word att det finns en "Senaste öppnade filer" och där fanns Excel-filen. Så det var bara att klicka på Infoga i e-mailen och välja dokument. Då kom jag precis rätt.

Visst finns det en knapp!

image.png.29f5619f20734c3d1be32db5c06543c4.png

Du tar fram den genom att fälla ner den lilla pilen till höger och klicka på E-mail så visas den.

 

Dela detta inlägg


Länk till inlägg
Dela på andra webbplatser

Vad bra att det löste sig enkelt.. 

gsb@ Den enklaste lösningen simmade förbi.. Tack för tipset :)

Dela detta inlägg


Länk till inlägg
Dela på andra webbplatser

Join the conversation

You can post now and register later. If you have an account, sign in now to post with your account.

Gäst
Svara i detta ämne...

×   Du har klistrat in innehåll med formatering.   Ta bort formatering

  Only 75 emoji are allowed.

×   Din länk har automatiskt bäddats in.   Visa som länk istället

×   Your previous content has been restored.   Clear editor

×   You cannot paste images directly. Upload or insert images from URL.

Laddar...