Jump to content

Artiklar på kampanj, många veckor i rad. Vilken formel?


Recommended Posts

Hej!

 

Jag funderar på om det finns något bra sätt att lösa ett problem som jag har på jobbet.
Jag har ett dokument där jag fyller i alla artikelnummer som är på kampanj, och för att undvika att ha dem på kampanj för många veckor i rad så skulle jag behöva logga det lite bättre. Det rör sig om ca 3000 artikelnummer som varierar från vecka till vecka. Jag lägger upp ett exempeldokument med två frågeställningar.


Hur hade ni lättast löst detta? 

Bok2.xlsx

Link to comment
Share on other sites

Fråga 1

Du kan kolla hur många celler som är = artikelnumret  OCH cellen till höger
=(C3:M3=D3:N3)*(C3:M3=B3)

Eller lika med cellen till vänster
=(C3:M3=B3:L3)*(C3:M3=B3)

slå ihop (kolla om minst en av dem är 1):
=(((C3:M3=D3:N3)*(C3:M3=B3)+(C3:M3=B3:L3)*(C3:M3=B3))>0)*1

och summera
=SUMMA((((C3:M3=D3:N3)*(C3:M3=B3)+(C3:M3=B3:L3)*(C3:M3=B3))>0)*1)

Problemet är att första data-kolumnen alltid blir 1 eftersom det står samma sak i Artikelnummer så den får du trolla bort (om den inte är lika med efterföljande..). 

=SUMMA((((C3:M3=D3:N3)*(C3:M3=B3)+(C3:M3=B3:L3)*(C3:M3=B3))>0)*1)-(B3=C3)*(C3<>D3)

fråga2;

så här kan du få en lista

=FILTER(C2:M2;C3:M3=B3)

eller hårdkodat med texten "AA"

=FILTER(C2:M2;C3:M3="AA")

Eller om du vill ha det i en cell

=TEXTJOIN(", ";;FILTER(C2:M2;C3:M3="AA"))

=TEXTJOIN(", ";;OM(C3:M3="AA";C2:M2;""))

Om du bara vill ha siffrorna kan du ta bort texten "Vecka "

=BYT.UT(TEXTJOIN(", ";;FILTER($C$2:$M$2;C3:M3="AA"));"Vecka ";"")

Link to comment
Share on other sites

Join the conversation

You can post now and register later. If you have an account, sign in now to post with your account.

Guest
Reply to this topic...

×   Pasted as rich text.   Paste as plain text instead

  Only 75 emoji are allowed.

×   Your link has been automatically embedded.   Display as a link instead

×   Your previous content has been restored.   Clear editor

×   You cannot paste images directly. Upload or insert images from URL.

Loading...
 Share

×
×
  • Create New...